Arduino Tutorial

By LiterallyTheOne

7: I2C: Part 1

Introduction

• Previous tutorial: Interrupt
• This tutorial: I2C

I2C Communication

• Inter-Integrated Circuit
• 2 Wire
• Short-distance

I2C Pins

• SDA: Serial Data
• SCL: Serial Clock

Master and Slave

• Master: 1
• Slave: multiple
• We can connect multiple components to the same pins

Master's privileges

• Controls the clock on SCL
• Decides that if it wants to communicate with slaves

Communication structure

I2C pins in Arduino Uno

Wire

• Library to control I2C Communication in Arduino
• Include Wire:

#include <Wire.h>

• Initilize Wire:

Wire.begin();

Different communication with an slave

• Read
• Write

Write

// start the communication in order to write
// with the slave with the address of `addr`
Wire.beginTransmission(addr);   
Wire.write(data);               // write data
Wire.endTransmission();         // finish transmission

Read

// start a read communication with the slave
// with the address of `addr` and read `number` bytes
Wire.requestFrom(addr, number);
Wire.read();                    // read bytes

Connect a Clock to an Arduino

• DS1307: Micro/Peripherals/DS1307

Code to scan

#include <Arduino.h>
#include <Wire.h>

void setup()
{
  Wire.begin();
  Serial.begin(9600);
}

void loop()
{
  for (int i = 0; i < 127; i++)
  {
    Wire.beginTransmission(i);
    if (Wire.endTransmission() == 0)
    {
      Serial.println("Device found at address: 0x" + String(i, HEX));
    }
  }
  delay(2000);
}

Connect OLED

• SSD1306: Outputs/Displays/SSD1306

Connect Temperature

• DS1621: Micro/Sensors/DS1621

Clock: DS1307

• Real-Time Clock (RTC) integrated circuit
• keeps track of the current time and date
• Battery

DS1307 registers

Way that it stores data

• Storing: 0x22 -> 22
• Not 2*16+2

DS1307: Define global variables

#define DS1307_ADDRESS 0x68

#define TIME_READ 7

// seconds, minutes, hours, weekday, day, month, year
byte time[TIME_READ];

DS1307: Function to read

void read_date_and_time()
{
  Wire.beginTransmission(DS1307_ADDRESS);
  Wire.write(0x00);
  Wire.endTransmission();

  Wire.requestFrom(DS1307_ADDRESS, 7);

  for (int i = 0; i < TIME_READ; i++)
  {
    time[i] = Wire.read();
  }
}

DS1307: Display in Serial

for (int i = 0; i < TIME_READ; i++)
{
  int time_int = 0;
  time_int = (time[i] / 16) * 10 + time[i] % 16;
  Serial.print(String(time_int) + " ");
}
Serial.println();

DS1307: Read output

DS1307: Write

void write_date_and_time(int *time_to_write)
{
  Wire.beginTransmission(DS1307_ADDRESS);
  Wire.write(0x00);

  for (int i = 0; i < TIME_READ; i++)
  {
    byte time_byte = (time_to_write[i] / 10) * 16 + time_to_write[i] % 10;
    Wire.write(time_byte);
  }
  Wire.endTransmission();
}

DS1307: Example

int time_to_write[7] = {
    20, // second
    30, // minute
    11, // hour
    7,  // day of the week
    23, // day of the month
    11, // month
    25, // year
};
write_date_and_time(time_to_write);

DS1307: Write output

OLED: SSD1306

• OLED (Organic Light Emitting Diode)
• Graphic display modules

AdaFruit

• Library to control graphics
• Add to platfomIO

lib_deps =
    Adafruit SSD1306
    Adafruit GFX Library

• Include

#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>

SSD1306: global variables

#define SCREEN_WIDTH 128
#define SCREEN_HEIGHT 64

Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire);

SSD1306: setup

if (!display.begin(SSD1306_SWITCHCAPVCC, SSD1306_ADDRESS))
{
Serial.println("SSD1306 failed!");
for (;;)
  ;
}

display.setTextSize(1);
display.setTextColor(WHITE, BLACK);

SSD1306: display

display.clearDisplay();
display.setCursor(0, 0);

display.print("Hello World!");
display.display();

SSD1306: Show the clock

OLED ball

OLED ball line

Link to the tutorial and materials